perm filename PIX.SAI[PIX,HPM]16 blob
sn#197490 filedate 1976-01-22 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00034 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00005 00002 BEGIN "PIX"
C00008 00003 IF CHR="?" THEN
C00011 00004 IF CHR="T" THEN comment take a picture via a camera
C00013 00005 IF CHR="↑" THEN comment optimize clip levels
C00018 00006 IF CHR='175 THEN comment alter camera number
C00019 00007 IF CHR="B" THEN comment alter bits/pixel and # to average
C00020 00008 IF CHR="I" THEN comment input a file
C00022 00009 IF CHR="O" THEN comment output a file
C00023 00010 IF CHR="D" THEN comment video synthesizer display
C00026 00011 IF CHR="H" THEN comment high quality halftone
C00030 00012 IF CHR="R" THEN comment random halftone
C00032 00013 IF CHR="A" THEN comment arty bug halftone
C00034 00014 IF CHR="X" THEN comment send previous halftone to the XGP
C00035 00015 IF CHR="#" THEN comment switch a video switch output
C00036 00016 IF CHR="P" THEN comment list a picture on the tty
C00039 00017 IF CHR="C" THEN comment step past a certain number of pictures
C00040 00018 IF CHR="K" THEN comment clear the video synthesizer
C00041 00019 IF CHR="*" THEN comment gronk synthesizer intensity table
C00043 00020 IF CHR="S" THEN comment change size of displays
C00050 00021 IF CHR="F" THEN comment high pass filter
C00051 00022 IF CHR="L" THEN comment low pass filter
C00052 00023 IF CHR="W" THEN comment select a window
C00054 00024 IF CHR="Z" THEN comment change size of a picture
C00056 00025 IF CHR="N" THEN comment apply noise remover
C00057 00026 IF CHR="V" THEN comment apply interest operator
C00058 00027 IF CHR="M" THEN comment pixel modification
C00060 00028 IF CHR="G" THEN comment graph a histogram
C00063 00029 IF CHR="J" THEN comment graph a histogram
C00066 00030 IF CHR="E" THEN comment apply histogram normalizer
C00067 00031 IF CHR="Y" THEN comment apply vert sync loss correction
C00068 00032 IF CHR="Q" THEN comment exit
C00069 00033 BEGIN comment an unrecognized character
C00071 00034 END
C00074 ENDMK
C⊗;
BEGIN "PIX"
REQUIRE "VIXHDR.SAI[VIS,HPM]" SOURCE_FILE;
require "outdd.rel[s,pmf]" load_module;
external procedure outdd(string s);
INTEGER CAMERA,CHR,HIG,WID,BITS,PWANT,PHAVE,PDEFAULT;
STRING BACKLOG; REAL SSIZE,HSIZE,SASPECT,HASPECT;
INTEGER SDISWID,SDISHIG,SYPOS;
INTEGER HDISWID,HDISHIG,HAPOS;
BOOLEAN INITED,SYNLAS,HAFTONE;
INTEGER BCL,TCL,SUMS;
boolean outddcalled;
REAL TASPECT,TLEN,TWID;
INTEGER PROCEDURE UCONV(INTEGER I);
RETURN(IF I>'140 ∧ I≤'172 THEN I LAND '137 ELSE I);
BCL←7; TCL←0;
CAMERA←'54; BACKLOG←""; INITED←FALSE; SYNLAS←TRUE; HAFTONE←FALSE;
TASPECT←6/10; TLEN←60; TWID←60;
HIG←262; WID←300; BITS←4; SUMS←1;
SSIZE←HSIZE←.5; SASPECT←HASPECT←3/4;
SDISWID←HDISWID←SDISHIG←HDISHIG←1; HAPOS←SYPOS←1;
PDEFAULT←PWANT←PHAVE←PIXDIM(HIG,WID,BITS);
DDINIT; SCREEN(-1,-1,1,1);
synmap(0,-1);
outddcalled←false;
OUTSTR("TYPE ? FOR HELP"&'15&'12);
WHILE TRUE DO
BEGIN
INTEGER ARRAY PIC[0:PHAVE];
IF PHAVE=PDEFAULT THEN
BEGIN
MAKPIX(HIG,WID,BITS,PIC[0]);
INITED←TRUE;
END;
WHILE PHAVE=PWANT DO
BEGIN
IF LENGTH(BACKLOG)=0 THEN
BEGIN
OUTSTR("*");
DO CHR←UCONV(INCHRW) UNTIL CHR≠'15;
END
ELSE CHR←UCONV(LOP(BACKLOG));
IF CHR="?" THEN
BEGIN
outddcalled←true;
OUTdd(" Pix Commands
""T"" to take a picture from currently selected source
""↑"" to optimize camera digitizer clip levels. default= 7,0
<altmode> to set video source. default=44, the new cart reciever
""B"" to set digitizer bits/sample, no of frames to average. default= 4,1
""I"" or ""O"" to input or output pictures from or to a file
""D"" to display the current picture on the video synthesizer
""H"", ""R"" or ""A"" to display it as a halftone (H good, R random, A arty)
""P"" to print it out as a character display (halftone) on the terminal
""S"" to set multiplicity, shape and size of displays. default=1x1, 1/2 size
""C"" to skip past a number of slots (when displaying multiple pictures)
""K"" to clear the video synthesizer
""*"" to adjust the video intensity table
""#"" to connect a foreign video switch line to a given channel
""X"" to output the most recent data disc display on the XGP
""Y"" to fix a picture with lost vertical sync (rolled in the y direction)
""Z"" to change the height, width and bits/pixel of the picture
""W"" to select a window from the picture
""F"", ""L"", ""N"" or ""V"" to filter the picture
F high pass, L low pass (halve resolution), N remove noise, V interest
""G"" or ""J"" to graph the numbers of each grey level. G raw, J integrated
""E"" to enhance a picture (normalize the instances of each grey level)
""M"" to modify grey levels via a function (entered piecewise linear)
""Q"" to quit
");
OUTSTR('15&'12);
END
ELSE
IF CHR="T" THEN comment take a picture via a camera;
BEGIN
INTEGER NRT;
IF PHAVE=PDEFAULT THEN
BEGIN
IF ¬INITED THEN
BEGIN
MAKPIX(HIG,WID,BITS,PIC[0]);
INITED←TRUE;
END;
NRT←CAMPIX(CAMERA,0,2,PIC[0],SUMS,BCL,TCL);
OUTSTR(" "&(IF NRT<0 THEN " aborted" ELSE
CVS(NRT)&" RETR"&(IF NRT≠1 THEN "IES" ELSE "Y"))&'15&'12);
IF NRT≥0 THEN
OUTSTR(CVS(PIC[PCLN])&" LINES x "&CVS(PIC[LNBY])&
" BYTES/LINE x "&CVS(PIC[BYBI])&" BITS/BYTE"&'15&'12);
END
ELSE
BEGIN
BACKLOG←"T";
PWANT←PDEFAULT;
END;
END
ELSE
IF CHR="↑" THEN comment optimize clip levels;
BEGIN
STRING SIN; INTEGER FOO;
OUTSTR("<CR> FOR AUTO OR TCLIP, BCLIP (0≤TCLIP≤BCLIP≤7):"); SIN←INCHWL;
IF LENGTH(SIN)≠0 THEN
BEGIN
TCL←INTSCAN(SIN,FOO);
BCL←INTSCAN(SIN,FOO);
END
ELSE
BEGIN
INTEGER ARRAY T[0:PIXDIM(100,200,4)];
INTEGER NRT;
MAKPIX(100,200,4,T[0]);
NRT←CAMPIX(CAMERA,75,50,T[0],1,BCL←7,TCL←0);
OUTSTR(" "&(IF NRT<0 THEN " aborted" ELSE
CVS(NRT)&" RETR"&(IF NRT≠1 THEN "IES" ELSE "Y"))&'15&'12);
IF NRT≥0 THEN
BEGIN
INTEGER ARRAY TT[0:15];
INTEGER I,S,P;
HISTOG(T[0],TT[0]);
S←0;
FOR I←0 STEP 1 UNTIL 7 DO S←S+(TT[I]←TT[2*I]+TT[2*I+1]);
TCL←0; P←0; WHILE (P←P+TT[7-TCL])<S%12 DO TCL←TCL+1;
BCL←7; P←0; WHILE (P←P+TT[7-BCL])<S%12 DO BCL←BCL-1;
OUTSTR("TCLIP="&CVS(TCL)&" BCLIP="&CVS(BCL)&'15&'12);
END;
END;
END
ELSE
IF CHR='175 THEN comment alter camera number;
BEGIN
OUTSTR(" CHANNEL NUMBER:");
CAMERA←CVO(INCHWL);
BCL←7; TCL←0;
END
ELSE
IF CHR="B" THEN comment alter bits/pixel and # to average;
BEGIN
INTEGER T;
OUTSTR(" BITS/PIXEL (NOW "&CVS(BITS)&"):");
T←CVD(INCHWL); IF T>0 THEN BITS←T MIN 36;
PDEFAULT←PWANT←PIXDIM(HIG,WID,BITS);
OUTSTR(" NO. OF PICTURES TO AVERAGE (NOW "&CVS(SUMS)&"):");
T←CVD(INCHWL); IF T>0 THEN SUMS←T;
END
ELSE
IF CHR="I" THEN comment input a file;
BEGIN
STRING FN;
IF LENGTH(BACKLOG)=0 THEN
BEGIN
OUTSTR("FILE:");
IF LENGTH(FN←INCHWL)>0 ∧ PFLDIM(FN)>0 THEN
BEGIN
PWANT←PFLDIM(FN);
BACKLOG←"I"&FN;
END ELSE OUTSTR("aborted"&'15&'12);
END
ELSE
BEGIN
GETPFL(BACKLOG,PIC[0]);
OUTSTR(CVS(PIC[PCLN])&" LINES x "&CVS(PIC[LNBY])&
" BYTES/LINE x "&CVS(PIC[BYBI])&" BITS/BYTE"&'15&'12);
BACKLOG←"";
INITED←FALSE;
END;
END
ELSE
IF CHR="O" THEN comment output a file;
BEGIN
STRING FN;
OUTSTR("FILE:");
IF LENGTH(FN←INCHWL)≠0 THEN PUTPFL(PIC[0],FN)
ELSE OUTSTR("aborted"&'15&'12);
END
ELSE
IF CHR="D" THEN comment video synthesizer display;
BEGIN
INTEGER I,J;
REAL SX,SY,ASP,ASPEN;
REAL PX,PY; INTEGER MODP;
SYNLAS←TRUE;
MODP←SYPOS MOD (SDISWID*SDISHIG);
PX←MODP MOD SDISWID;
MODP←MODP%SDISWID;
PY←SDISHIG-MODP-1;
PX←2*PX-SDISWID+1;
PY←2*PY-SDISHIG+1;
SX←1; SY←1; ASPEN←SASPECT*SDISWID/SDISHIG;
ASP←PIC[PCLN]/PIC[LNBY];
IF ASP>ASPEN THEN SX←ASPEN/ASP ELSE SY←ASP/ASPEN;
SX←SX*SSIZE; SY←SY*SSIZE;
SETFORMAT(0,2);
SCREEN(-SDISWID,-SDISHIG,SDISWID,SDISHIG);
FOR I←0 STEP 1 UNTIL PIC[BYBI]-1 DO
IF SYNMAP(I)>0 ∨ SDISHIG*SDISWID>1 THEN
BEGIN
IF SDISHIG*SDISWID>1 THEN GETDDF("DD"&CVS(I)&".TMP[TMP,HPM]");
DRKEN; RECTAN(PX-1,PY-1,PX+1,PY+1);
VID(PX-SX,PY-SY,PX+SX,PY+SY,PIC[0],1 LSH (PIC[BYBI]-I-1));
IF SYNMAP(I)>0 THEN
BEGIN
ERASE(SYNMAP(I));
FOR J←1,1,1 DO DPYUP(SYNMAP(I));
END;
SHOWA('47);
IF SDISHIG*SDISWID>1 THEN PUTDDF("DD"&CVS(I)&".TMP[TMP,HPM]");
END;
HAFTONE←TRUE;
SYPOS←SYPOS+1;
OUTSTR('15&'12&"*");
SHOW('47);
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
SHOW(-1);
END
ELSE
IF CHR="H" THEN comment high quality halftone;
BEGIN
INTEGER J,CHN;
REAL SX,SY,ASP,ASPEN;
REAL PX,PY; INTEGER MODP;
SYNLAS←FALSE;
MODP←HAPOS MOD (HDISWID*HDISHIG);
PX←MODP MOD HDISWID;
MODP←MODP%HDISWID;
PY←HDISHIG-MODP-1;
PX←2*PX-HDISWID+1;
PY←2*PY-HDISHIG+1;
SX←1; SY←1; ASPEN←HASPECT*HDISWID/HDISHIG;
ASP←PIC[PCLN]/PIC[LNBY];
IF ASP>ASPEN THEN SX←ASPEN/ASP ELSE SY←ASP/ASPEN;
SX←SX*HSIZE; SY←SY*HSIZE;
SCREEN(-HDISWID,-HDISHIG,HDISWID,HDISHIG);
IF HDISHIG*HDISWID>1 THEN GETDDF("DD.TMP[TMP,HPM]");
DRKEN; RECTAN(PX-1,PY-1,PX+1,PY+1);
VIDEO(PX-SX,PY-SY,PX+SX,PY+SY,PIC[0],-2);
CHN←GDDCHN(-1);
ERASE(CHN);
FOR J←1,1,1,1,1,1 DO DPYUP(CHN);
OUTSTR(" CHANNEL "&CVOS(CHN)&'15&'12);
SHOW(CHN);
HAFTONE←TRUE;
IF HDISHIG*HDISWID>1 THEN PUTDDF("DD.TMP[TMP,HPM]");
HAPOS←HAPOS+1;
OUTSTR("*");
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
SHOW(-1);
RDDCHN(CHN);
END
ELSE
IF CHR="R" THEN comment random halftone;
BEGIN
INTEGER J,CHN;
REAL SX,SY,ASP,ASPEN;
REAL PX,PY; INTEGER MODP;
SYNLAS←FALSE;
MODP←HAPOS MOD (HDISWID*HDISHIG);
PX←MODP MOD HDISWID;
MODP←MODP%HDISWID;
PY←HDISHIG-MODP-1;
PX←2*PX-HDISWID+1;
PY←2*PY-HDISHIG+1;
SX←1; SY←1; ASPEN←HASPECT*HDISWID/HDISHIG;
ASP←PIC[PCLN]/PIC[LNBY];
IF ASP>ASPEN THEN SX←ASPEN/ASP ELSE SY←ASP/ASPEN;
SX←SX*HSIZE; SY←SY*HSIZE;
SCREEN(-HDISWID,-HDISHIG,HDISWID,HDISHIG);
IF HDISHIG*HDISWID>1 THEN GETDDF("DD.TMP[TMP,HPM]");
DRKEN; RECTAN(PX-1,PY-1,PX+1,PY+1);
VID(PX-SX,PY-SY,PX+SX,PY+SY,PIC[0],-1);
CHN←GDDCHN(-1);
OUTSTR(" CHANNEL "&CVOS(CHN)&'15&'12);
ERASE(CHN);
FOR J←1,1,1,1,1,1 DO DPYUP(CHN);
SHOW(CHN);
HAFTONE←TRUE;
IF HDISHIG*HDISWID>1 THEN PUTDDF("DD.TMP[TMP,HPM]");
HAPOS←HAPOS+1;
OUTSTR("*");
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
SHOW(-1);
RDDCHN(CHN);
END
ELSE
IF CHR="A" THEN comment arty bug halftone;
BEGIN
INTEGER J,CHN;
REAL SX,SY,ASP,ASPEN;
REAL PX,PY; INTEGER MODP;
SYNLAS←FALSE;
MODP←HAPOS MOD (HDISWID*HDISHIG);
PX←MODP MOD HDISWID;
MODP←MODP%HDISWID;
PY←HDISHIG-MODP-1;
PX←2*PX-HDISWID+1;
PY←2*PY-HDISHIG+1;
SX←1; SY←1; ASPEN←HASPECT*HDISWID/HDISHIG;
ASP←PIC[PCLN]/PIC[LNBY];
IF ASP>ASPEN THEN SX←ASPEN/ASP ELSE SY←ASP/ASPEN;
SX←SX*HSIZE; SY←SY*HSIZE;
SCREEN(-HDISWID,-HDISHIG,HDISWID,HDISHIG);
IF HDISHIG*HDISWID>1 THEN GETDDF("DD.TMP[TMP,HPM]");
DRKEN; RECTAN(PX-1,PY-1,PX+1,PY+1);
VIDEO(PX-SX,PY-SY,PX+SX,PY+SY,PIC[0],-4);
CHN←GDDCHN(-1);
ERASE(CHN);
FOR J←1,1,1,1,1,1 DO DPYUP(CHN);
OUTSTR(" CHANNEL "&CVOS(CHN)&'15&'12);
SHOW(CHN);
HAFTONE←TRUE;
IF HDISHIG*HDISWID>1 THEN PUTDDF("DD.TMP[TMP,HPM]");
HAPOS←HAPOS+1;
OUTSTR("*");
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
SHOW(-1);
RDDCHN(CHN);
END
ELSE
IF CHR="X" THEN comment send previous halftone to the XGP;
BEGIN
INTEGER J;
OUTSTR("SIZE (-5 to +5):");
J←CVD(INCHWL);
IF J≠0 THEN
BEGIN
IF HAFTONE THEN BEGIN INVEN; RECTAN(-1000,-1000,1000,1000); END;
XGPUP(J);
IF HAFTONE THEN BEGIN INVEN; RECTAN(-1000,-1000,1000,1000); END;
END
ELSE
OUTSTR("aborted"&'15&'12);
END
ELSE
IF CHR="#" THEN comment switch a video switch output;
BEGIN
INTEGER J,K;
OUTSTR(" LINE:"); J←CVO(INCHWL);
OUTSTR("CHANNEL:"); K←CVO(INCHWL);
SHOW(K,J);
END
ELSE
IF CHR="P" THEN comment list a picture on the tty;
BEGIN
INTEGER I,J,K,L,M;
REAL ASP;
INTEGER SX,SY;
ASP←PIC[PCLN]/PIC[LNBY];
SX←TWID; SY←SX*ASP*TASPECT;
IF SY>TLEN THEN BEGIN SX←SX*TLEN/SY; SY←TLEN; END;
BEGIN
REAL ARRAY TMP[-1:SY,-1:SX];
REAL PCMAX;
PCMAX←2↑PIC[BYBI]-1;
FOR I←0 STEP 1 UNTIL SX-1 DO
FOR J←0 STEP 1 UNTIL SY-1 DO
TMP[J,I]←PIXEL(PIC[0],PIC[PCLN]*J%SY,PIC[LNBY]*I%SX)/PCMAX;
CALL(0,"RESET");
OUTSTR('15&'12);
FOR J←0 STEP 1 UNTIL SY-1 DO
BEGIN
FOR I←0 STEP 1 UNTIL SX-1 DO
BEGIN
REAL ERR;
IF (ERR←TMP[J,I])<0.5 THEN OUTSTR("*") ELSE
BEGIN
OUTSTR(" ");
ERR←ERR-1;
END;
ERR←ERR/16;
TMP[J+1,I-1]←TMP[J+1,I-1]+3*ERR;
TMP[J+1,I]←TMP[J+1,I]+5*ERR;
TMP[J+1,I+1]←TMP[J+1,I+1]+ERR;
TMP[J,I+1]←TMP[J,I+1]+7*ERR;
END;
OUTSTR('15&'12);
END;
END;
END
ELSE
IF CHR="C" THEN comment step past a certain number of pictures;
BEGIN
INTEGER T;
OUTSTR("SKIP HOW MANY (NEGATIVE TO BACKSPACE):");
T←CVD(INCHWL);
IF SYNLAS THEN SYPOS←SYPOS+T ELSE HAPOS←HAPOS+T;
END
ELSE
IF CHR="K" THEN comment clear the video synthesizer;
BEGIN
INTEGER T;
FOR T←0 STEP 1 UNTIL 7 DO ERASE(SYNMAP(T));
OUTSTR('15&'12);
END
ELSE
IF CHR="*" THEN comment gronk synthesizer intensity table;
BEGIN
STRING SI; INTEGER I;
OUTSTR("TRANSFER FUNCTION (about -2.0 to 2.0):");
IF ¬MAPMON(REALSCAN(SI←INCHWL,I)) THEN
OUTSTR("sorry, ELF not available"&'15&'12);
END
ELSE
IF CHR="S" THEN comment change size of displays;
BEGIN
STRING INP; INTEGER FOO,INC;
REAL T;
OUTSTR('15&'12&"FOR SYNTHESIZER, HALFTONES OR PRINTOUT (S, H OR P)?");
INC←UCONV(INCHWL);
IF INC="S" THEN
BEGIN
INTEGER I;
SYNLAS←TRUE;
SETFORMAT(0,2);
OUTSTR("PICTURE SIZE (1 IS FULLSIZE, NOW"&CVF(SSIZE)&"):"); INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T≠0 THEN SSIZE←ABS(T);
OUTSTR("ASPECT RATIO (HEIGHT/WIDTH OF SCREEN, NOW"&CVF(SASPECT)&"):");
INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T>0 THEN SASPECT←T;
OUTSTR("NUMBER OF PICTURES IN X DIRECTION:");
T←ABS(CVD(INCHWL));
IF T>0∧T≠SDISWID THEN
BEGIN
SDISWID←T;
SYPOS←0;
END;
OUTSTR("NUMBER OF PICTURES IN Y DIRECTION:");
T←ABS(CVD(INCHWL));
IF T>0∧T≠SDISHIG THEN
BEGIN
SDISHIG←T;
SYPOS←0;
END;
SCREEN(-1,-1,1,1);
DRKEN; RECTAN(-1000,-1000,1000,1000);
IF SDISHIG*SDISWID>1 THEN
BEGIN
OUTSTR("ERASE?");
IF UCONV(INCHWL)="Y" THEN
FOR I←0 STEP 1 UNTIL 7 DO
PUTDDF("DD"&CVS(I)&".TMP[TMP,HPM]")
ELSE
BEGIN
OUTSTR("REDRAW OLD DISPLAY NOW?");
IF UCONV(INCHWL)="Y" THEN
FOR I←0 STEP 1 UNTIL 7 DO
BEGIN
SHOWA('47);
GETDDF("DD"&CVS(I)&".TMP[TMP,HPM]");
ERASE(SYNMAP(I));
DPYUP(SYNMAP(I)); DPYUP(SYNMAP(I));
DPYUP(SYNMAP(I)); DPYUP(SYNMAP(I));
SHOWA('47);
END;
HAFTONE←TRUE;
OUTSTR("*");
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
END;
END;
END
ELSE IF INC="H" THEN
BEGIN
SYNLAS←FALSE;
SETFORMAT(0,2);
OUTSTR("PICTURE SIZE (1 IS FULLSIZE, NOW"&CVF(HSIZE)&"):"); INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T≠0 THEN HSIZE←ABS(T);
OUTSTR("ASPECT RATIO (HEIGHT/WIDTH OF SCREEN, NOW"&CVF(HASPECT)&"):");
INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T>0 THEN HASPECT←T;
OUTSTR("NUMBER OF PICTURES IN X DIRECTION:");
T←ABS(CVD(INCHWL));
IF T>0∧T≠HDISWID THEN
BEGIN
HDISWID←T;
HAPOS←0;
END;
OUTSTR("NUMBER OF PICTURES IN Y DIRECTION:");
T←ABS(CVD(INCHWL));
IF T>0∧T≠HDISHIG THEN
BEGIN
HDISHIG←T;
HAPOS←0;
END;
SCREEN(-1,-1,1,1);
DRKEN; RECTAN(-1000,-1000,1000,1000);
IF HDISHIG*HDISWID>1 THEN PUTDDF("DD.TMP[TMP,HPM]");
END
ELSE IF INC="P" THEN
BEGIN
SETFORMAT(0,2);
OUTSTR("ASPECT RATIO OF TTY (CHRS/IN, VERTICAL/HORIZONTAL, NOW "&
CVF(TASPECT)&"):");
INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T≠0 THEN TASPECT←ABS(T);
OUTSTR("WIDTH OF TTY DISPLAYS (NOW "&CVS(TWID)&"):");
INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T≠0 THEN TWID←ABS(T);
OUTSTR("MAXIMUM HEIGHT OF TTY DISPLAYS (NOW "&CVS(TLEN)&"):");
INP←INCHWL;
T←REALSCAN(INP,FOO);
IF T≠0 THEN TLEN←ABS(T);
END;
END
ELSE
IF CHR="F" THEN comment high pass filter;
BEGIN
INTEGER WINDOW;
OUTSTR(" WINDOW SIZE:");
WINDOW←CVD(INCHWL);
IF WINDOW>1 THEN
BEGIN
INTEGER ARRAY T[0:PHAVE];
PASSHI(PIC[0],WINDOW,T[0]);
ENHANCE(T[0]);
COPPIC(T[0],PIC[0]);
END
ELSE OUTSTR("aborted"&'15&'12);
END
ELSE
IF CHR="L" THEN comment low pass filter;
BEGIN
INTEGER ARRAY T[0:PHAVE];
IF PIC[PCLN]≥2∧PIC[LNBY]≥2 THEN
BEGIN
HAFPIC(PIC[0],T[0],8);
COPPIC(T[0],PIC[0]);
END;
PWANT←PHAVE←PIXDIM(PIC[PCLN],PIC[LNBY],PIC[BYBI]);
INITED←FALSE;
OUTSTR('15&'12);
OUTSTR(CVS(PIC[PCLN])&" LINES x "&CVS(PIC[LNBY])&
" BYTES/LINE x "&CVS(PIC[BYBI])&" BITS/BYTE"&'15&'12);
END
ELSE
IF CHR="W" THEN comment select a window;
BEGIN
INTEGER XL,XH,YL,YH,FOO;
STRING INFL;
OUTSTR('15&'12);
OUTSTR("LOW X, HIGH X (0 TO 1):"); INFL←INCHWL;
XL←REALSCAN(INFL,FOO)*PIC[LNBY];
XH←REALSCAN(INFL,FOO)*PIC[LNBY];
IF XL>XH THEN XL↔XH;
XL←XL MAX 0; XH←XH MIN (PIC[LNBY]-1);
OUTSTR("LOW Y, HIGH Y (0 TO 1):"); INFL←INCHWL;
YL←REALSCAN(INFL,FOO)*PIC[PCLN];
YH←REALSCAN(INFL,FOO)*PIC[PCLN];
IF YL>YH THEN YL↔YH;
YL←YL MAX 0; YH←YH MIN (PIC[PCLN]-1);
BEGIN
INTEGER ARRAY T[0:PIXDIM(YH-YL+1,XH-XL+1,PIC[BYBI])];
MAKPIX(YH-YL+1,XH-XL+1,PIC[BYBI],T[0]);
SELECT(PIC[0],YL,XL,T[0]);
COPPIC(T[0],PIC[0]);
OUTSTR(CVS(PIC[PCLN])&" LINES x "&CVS(PIC[LNBY])&
" BYTES/LINE x "&CVS(PIC[BYBI])&" BITS/BYTE"&'15&'12);
PWANT←PHAVE←PIXDIM(PIC[PCLN],PIC[LNBY],PIC[BYBI]);
INITED←FALSE;
END;
END
ELSE
IF CHR="Z" THEN comment change size of a picture;
BEGIN
INTEGER FOO;
STRING INFL;
IF LENGTH(BACKLOG)=0 THEN
BEGIN
OUTSTR('15&'12);
OUTSTR("DILATION FACTORS (EG. .5 = HALF SIZE) X, Y:"); INFL←INCHWL;
WID←ABS(REALSCAN(INFL,FOO))*PIC[LNBY]; IF WID=0 THEN WID←PIC[LNBY];
HIG←ABS(REALSCAN(INFL,FOO))*PIC[PCLN]; IF HIG=0 THEN HIG←PIC[PCLN];
OUTSTR("NUMBER OF BITS:"); BITS←(CVD(INCHWL) MIN 36);
IF BITS≤0 THEN BITS←PIC[BYBI];
IF BITS≠PIC[BYBI]∨WID≠PIC[LNBY]∨HIG≠PIC[PCLN] THEN
BEGIN
PUTPFL(PIC[0],"TMP.TMP[TMP,HPM]");
PWANT←PIXDIM(HIG,WID,BITS);
BACKLOG←"Z ";
END;
END
ELSE
BEGIN
INTEGER ARRAY T[0:PFLDIM("TMP.TMP[TMP,HPM]")];
GETPFL("TMP.TMP[TMP,HPM]",T[0]);
MAKPIX(HIG,WID,BITS,PIC[0]);
OUTSTR(CVS(PIC[PCLN])&" LINES x "&CVS(PIC[LNBY])&
" BYTES/LINE x "&CVS(PIC[BYBI])&" BITS/BYTE"&'15&'12);
SHRINK(T[0],PIC[0]);
BACKLOG←"";
INITED←FALSE;
END;
END
ELSE
IF CHR="N" THEN comment apply noise remover;
BEGIN
CLEAN(PIC[0]);
OUTSTR('15&'12);
END
ELSE
IF CHR="V" THEN comment apply interest operator;
BEGIN
INTEGER WINDOW;
OUTSTR(" WINDOW SIZE:"); WINDOW←CVD(INCHWL);
IF WINDOW≥1 THEN
BEGIN
INTEREST(PIC[0],WINDOW,PIC[0]);
OUTSTR(CVS(PIC[PCLN])&" LINES x "&CVS(PIC[LNBY])&
" BYTES/LINE x "&CVS(PIC[BYBI])&" BITS/BYTE"&'15&'12);
PWANT←PHAVE←PIXDIM(PIC[PCLN],PIC[LNBY],PIC[BYBI]);
INITED←FALSE;
END
ELSE OUTSTR("aborted"&'15&'12);
END
ELSE
IF CHR="M" THEN comment pixel modification;
BEGIN
PRELOAD_WITH -1;
OWN INTEGER ARRAY PERM[-1:1024];
STRING INP; INTEGER FOO,I,J;
INTEGER LAST,THIS;
IF PERM[-1]=PIC[BYBI] THEN
BEGIN
OUTSTR(" ENTER NEW TRANSFORM?");
INP←UCONV(INCHRW);
END ELSE INP←"Y";
OUTSTR('15&'12);
IF INP="Y" THEN
BEGIN
PERM[-1]←PIC[BYBI];
OUTSTR(CVS(2↑PIC[BYBI])&" TOTAL GREY LEVELS, ENTER HOW MANY:");
FOO←(CVD(INCHWL) MAX 2) MIN 2↑PIC[BYBI];
LAST←0;
FOR I←0 STEP 1 UNTIL FOO-1 DO
BEGIN
THIS←((1 ASH PIC[BYBI])-1)*I%(FOO-1);
OUTSTR(CVS(THIS)&"→");
PERM[THIS]←CVD(INCHWL);
IF THIS>LAST THEN
FOR J←LAST STEP 1 UNTIL THIS DO
PERM[J]←(PERM[LAST]*(THIS-J)+PERM[THIS]*(J-LAST))%(THIS-LAST);
LAST←THIS;
END;
FOR I←0 STEP 1 UNTIL 2↑PIC[BYBI]-1 DO
PERM[I]←(PERM[I] MAX 0) MIN (2↑PIC[BYBI]-1);
END;
PERBIT(PIC[0],PERM[0]);
END
ELSE
IF CHR="G" THEN comment graph a histogram;
BEGIN
INTEGER ARRAY HIST[0:2↑PIC[BYBI]];
INTEGER FOO,I,J,MAV,CHN;
CHN←GDDCHN(-1);
OUTSTR(" CHANNEL "&CVOS(CHN)&'15&'12);
FOO←2↑PIC[BYBI]-1;
HISTOG(PIC[0],HIST[0]);
SCREEN(-.3,-.2,1.1,1.2);
DRKEN; RECTAN(-100,-1000,1000,1000);
LITEN;
LINE(0,0,0,1); LINE(0,1,1,1);
LINE(1,1,1,0); LINE(1,0,0,0);
LINE(0,.5,1,.5); LINE(0,.25,1,.25); LINE(0,.75,1,.75);
LINE(.5,0,.5,1); LINE(.25,0,.25,1); LINE(.75,0,.75,1);
MAV←0; FOR I←0 STEP 1 UNTIL FOO DO MAV←MAV MAX HIST[I];
MAV←MAV+1;
FOR I←1 STEP 1 UNTIL FOO DO
LINE((I-1)/FOO,HIST[I-1]/MAV,I/FOO,HIST[I]/MAV);
TXTPOS(0,-1/10,1/24,1/12); TEXT("0");
TXTPOS(1-LENGTH(CVS(2↑PIC[BYBI]))/24,-1/10,1/24,1/12);
TEXT(CVS(2↑PIC[BYBI]-1));
TXTPOS(-.07,0,1/24,1/12); TEXT("0");
TXTPOS(-.07-(LENGTH(CVS(MAV))-1)/24,1-1/12,1/24,1/12); TEXT(CVS(MAV));
ERASE(CHN);
FOR J←1,1,1,1,1 DO DPYUP(CHN);
HAFTONE←FALSE;
SHOW(CHN);
OUTSTR("*");
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
RDDCHN(CHN);
SHOW(-1);
END
ELSE
IF CHR="J" THEN comment graph a histogram;
BEGIN
INTEGER ARRAY HIST[0:2↑PIC[BYBI]];
INTEGER FOO,I,J,L,MAV,CHN;
CHN←GDDCHN(-1);
OUTSTR(" CHANNEL "&CVOS(CHN)&'15&'12);
FOO←2↑PIC[BYBI]-1;
HISTOG(PIC[0],HIST[0]);
SCREEN(-.3,-.2,1.1,1.2);
DRKEN; RECTAN(-100,-1000,1000,1000);
LITEN;
LINE(0,0,0,1); LINE(0,1,1,1);
LINE(1,1,1,0); LINE(1,0,0,0);
LINE(0,.5,1,.5); LINE(0,.25,1,.25); LINE(0,.75,1,.75);
LINE(.5,0,.5,1); LINE(.25,0,.25,1); LINE(.75,0,.75,1);
MAV←0; FOR I←0 STEP 1 UNTIL FOO DO MAV←MAV + HIST[I];
L←J←0;
FOR I←1 STEP 1 UNTIL FOO DO
BEGIN
L←J;
J←J+HIST[I];
LINE((I-1)/FOO,L/MAV,I/FOO,J/MAV);
END;
TXTPOS(0,-1/10,1/24,1/12); TEXT("0");
TXTPOS(1-LENGTH(CVS(2↑PIC[BYBI]))/24,-1/10,1/24,1/12);
TEXT(CVS(2↑PIC[BYBI]-1));
TXTPOS(-.07,0,1/24,1/12); TEXT("0");
TXTPOS(-.07-(LENGTH(CVS(MAV))-1)/24,1-1/12,1/24,1/12); TEXT(CVS(MAV));
ERASE(CHN);
FOR J←1,1,1,1,1 DO DPYUP(CHN);
SHOW(CHN);
HAFTONE←FALSE;
OUTSTR("*");
DO BACKLOG←INCHRW UNTIL BACKLOG≠'15∧BACKLOG≠'12;
RDDCHN(CHN);
SHOW(-1);
END
ELSE
IF CHR="E" THEN comment apply histogram normalizer;
BEGIN
ENHANCE(PIC[0]);
OUTSTR('15&'12);
END
ELSE
IF CHR="Y" THEN comment apply vert sync loss correction;
BEGIN
SYNCHRONIZE(PIC[0]);
OUTSTR('15&'12);
END
ELSE
IF CHR="Q" THEN comment exit;
BEGIN
if outddcalled then OUTDD('40&'15&'12);
CALL(0,"EXIT");
END
ELSE
BEGIN comment an unrecognized character;
IF CHR='12 THEN OUTSTR('15) ELSE
OUTSTR("?"&'15&'12);
END;
END;
PHAVE←PWANT;
END;
END "PIX";